树脂镜片的雾状纹识别

吐个泡泡 发表于 2023-4-21 17:07
是这样吗

厉害厉害

厉害厉害厉害厉害厉害厉害厉害厉害

厉害厉害

*感觉主要就是镜片边缘亮区域干扰太强，先把亮区域去掉对比还是比较明显的，尝试试下
read_image (Image, 'D:/095727fj9565tlljlmq6w9.png')
decompose3 (Image, Image1, Image2, Image3)

*先把镜片边缘亮区域去掉
binary_threshold (Image1, Region, 'max_separability', 'dark', UsedThreshold)
connection (Region, ConnectedRegions)
select_shape_std (ConnectedRegions, SelectedRegions, 'max_area', 70)
fill_up (SelectedRegions, RegionFillUp)
*边缘亮区域干扰还在内缩一下
erosion_circle (RegionFillUp, RegionErosion, 11.)

*图像增强
gray_histo (RegionErosion, Image1, AbsoluteHisto, RelativeHisto)
Mask := AbsoluteHisto [>=] 100
Selected := select_mask([0:|Mask|-1], Mask)
MinGray := min(Selected)
MaxGray := max(Selected)
scale_image_range (Image1, ImageScaled, MinGray, MaxGray)
reduce_domain (ImageScaled, RegionErosion, ImageReduced)

mean_image (ImageReduced, ImageMean, 3, 3)
mean_image (ImageReduced, ImageMean1, 111, 111)
dyn_threshold (ImageMean, ImageMean1, RegionDynThresh, 15, 'light')
opening_circle (RegionDynThresh, RegionOpening, 5.5)
connection (RegionOpening, ConnectedRegions1)
select_shape_std (ConnectedRegions1, SelectedRegions1, 'max_area', 70)